The National Palace Museum Experience/The National Palace Museum Experience.iso/Programs/TimeLine.dxr/00010.ls

Text File | 1998-11-19 | 4.6 KB | 174 lines

global gbarsprite, gslidersprite, returnframe, infoarea

on prepareMovie
  set gbarsprite to 43
  set gslidersprite to 45
  set infoarea to 36
  puppetSprite(gslidersprite, 1)
end

on startMovie
  if soundBusy(1) then
    sound stop 1
  end if
  playthesound(1, "..\Audio\Music2.wav")
  set returnlist to value(field "TimeLine Location")
  if getProp(returnlist, #flag) = 1 then
    set jumpframe to getProp(returnlist, #framenumber)
    set the rect of sprite gslidersprite to getProp(returnlist, #slider)
    put "[#FrameNumber:" && the frame & ", #Slider:" && the rect of sprite gslidersprite & ", #Flag: 0]" into field "TimeLine Location"
    go(jumpframe)
  end if
end

on dragslider
  set barleft to the left of sprite gbarsprite
  set barright to the right of sprite gbarsprite
  repeat while the mouseDown = 1
    set mh to the mouseH
    if mh <= barleft then
      set the locH of sprite gslidersprite to barleft
    else
      if mh >= barright then
        set the locH of sprite gslidersprite to barright
      else
        set the locH of sprite gslidersprite to mh
      end if
    end if
    set sliderloc to the locH of sprite gslidersprite
    set sliderloc to sliderloc - the left of sprite gbarsprite
    set the locV of sprite gslidersprite to 480 - sliderloc
    setframebyslider()
    updateStage()
  end repeat
end

on setframebyslider
  set sliderloc to the locH of sprite gslidersprite
  if sliderloc = 213 then
    go("D1")
    exit
  end if
  set sliderloc to sliderloc - the left of sprite gbarsprite
  set sliderloc to float(sliderloc)
  set ratio to sliderloc / the width of sprite gbarsprite
  set endframe to label("End")
  set mtime to ratio * endframe
  if mtime < 1 then
    set mtime to 1
  else
    if mtime > endframe then
      set mtime to endframe
    else
      go(integer(mtime))
    end if
  end if
end

on setsliderbyframe
  set ratio to the frame / 48
  set sliderloc to integer(ratio * the width of sprite gbarsprite)
  set sliderloc to sliderloc + the left of sprite gbarsprite
  set the locH of sprite gslidersprite to sliderloc
end

on othermenu menuname
  global menuflag
  set returnframe to the frame
  puppetSprite(12, 1)
  puppetSprite(45, 1)
  puppetSprite(57, 1)
  repeat with spriteNum = 15 to 30
    puppetSprite(spriteNum, 1)
  end repeat
  set menuflag to 1
  go(menuname)
end

on gobackfromexit
  puppetSprite(12, 0)
  puppetSprite(57, 0)
  updateStage()
  go(returnframe)
end

on showinfo
  set mycursor to the number of member "hand"
  set mycursormask to the number of member "hand mask"
  puppetSprite(infoarea, 1)
  if the mouseCast > 0 then
    set mouseovermember to the name of the mouseMember
    set mheadchar to chars(mouseovermember, 1, length(mouseovermember) - 1)
    if the last char in mouseovermember = "B" then
      set the memberNum of sprite infoarea to the number of member (mheadchar & "C")
      if char 1 of mouseovermember = "F" then
        cursor([mycursor, mycursormask])
        if the mouseDown then
          puppetSound(2, "Button")
          updateStage()
          toobjectmovie(chars(mouseovermember, 2, 7))
        end if
      else
        cursor(-1)
      end if
    else
      cursor(-1)
      puppetSprite(infoarea, 0)
    end if
  end if
end

on checkstate
  global menuflag
  repeat with spriteNum = 15 to 30
    set the blend of sprite spriteNum to 100
    if menuflag = 1 then
      puppetSprite(spriteNum, 0)
    end if
  end repeat
  set menuflag to 0
end

on switchdynasty whichdynasty
  case whichdynasty of
    "D1":
      puppetSprite(gslidersprite, 0)
    "D2":
      set the rect of sprite gslidersprite to rect(206, 461, 232, 487)
    "D3":
      set the rect of sprite gslidersprite to rect(234, 433, 260, 459)
    "D4":
      set the rect of sprite gslidersprite to rect(248, 419, 274, 445)
    "D5":
      set the rect of sprite gslidersprite to rect(256, 411, 282, 437)
    "D6":
      set the rect of sprite gslidersprite to rect(266, 401, 292, 427)
    "D7":
      set the rect of sprite gslidersprite to rect(275, 392, 301, 418)
    "D8":
      set the rect of sprite gslidersprite to rect(280, 387, 306, 413)
    "D9":
      set the rect of sprite gslidersprite to rect(289, 378, 315, 404)
  end case
  go(whichdynasty)
end

on stopMovie
  if the frame <> (marker("MainMenu") + 3) then
    set currentframe to the frame
  else
    set currentframe to returnframe
  end if
  put "[#FrameNumber:" && currentframe & ",#Slider:" && the rect of sprite gslidersprite & ", #Flag: 1]" into field "TimeLine Location"
  gobackpath()
end

on toobjectmovie newfile
  put newfile into field "Current Object"
  go(1, "Object")
end

on idle
  soundwait(1, "..\Audio\Music2.wav")
end